Mikrotik - отправляем backup на почту

Создаем скрипт backupemail

 {

#Create Variables

:local emailAddress "test@gmail.com"

#

:log info "Starting Backup Script...";

:local sysname [/system identity get name];

:local sysver [/system package get system version];

:log info "Flushing DNS cache...";

/ip dns cache flush;

:delay 2;

:log info "Deleting last Backups...";

:foreach i in=[/file find] do={:if ([:typeof [:find [/file get $i name] "$sysname-backup-"]]!="nil") do={/file remove $i}};

:delay 2;

#Create and E-mail Full Backup

:local backupfile ("$sysname-backup-" . [:pick [/system clock get date] 7 11] . [:pick [/system clock get date] 0 3] . [:pick [/system clock get date] 4 6] . ".backup");

:log info "Creating new Full Backup file...";

/system backup save name=$backupfile;

:delay 2;

:log info "Sending Full Backup file via E-mail...";

#/tool e-mail send from=$EaccountFrom to=$EaccountTo server=$smtpserv port=587 user=$EaccountFrom password=$pass start-tls=yes \

/tool e-mail send to=$emailAddress start-tls=yes \

      file=$backupfile subject=("$sysname Full Backup (" . [/system clock get date] . ")") \

      body=("$sysname full Backup file see in attachment. \nRouterOS version: $sysver.");

:delay 5;

#Create and E-mail Setup Backup

:local exportfile ("$sysname-backup-" . [:pick [/system clock get date] 7 11] . [:pick [/system clock get date] 0 3] . [:pick [/system clock get date] 4 6] . ".rsc");

:log info "Creating new Setup Script file...";

/export file=$exportfile;

:delay 2;

:log info "Sending Setup Script file via E-mail...";

#/tool e-mail send from=$EaccountFrom to=$EaccountTo server=$smtpserv port=587 user=$EaccountFrom password=$pass start-tls=yes \

/tool e-mail send to=$emailAddress start-tls=yes \

      file=$exportfile subject=("$sysname Setup Script Backup (" . [/system clock get date] . ")") \

      body=("$sysname Setup Script file see in attachment. \nRouterOS version: $sysver.");

:delay 5;

#Finish

:log info "All System Backups emailed successfully.\nBackuping completed.";

}

Добавляем scheduler 

/system scheduler add name=backupemail start-time=13:00:00 interval=7d 

Event

system script run backupemail